;cleanhmbc.ab
;avance-version (2008-08-14)
;
;CLEAN-HMBC
;Echo/Antiecho gradient selection
;with second order low-pass J-filter and an adiabatic
;gradient based J filter
;

;$OWNER=awbn
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

define list<gradient> EA1={1.0000 -1.0000}
define list<gradient> EA2={-1.0000 1.0000}

"d0 =3u"
"d11=30m"
"p2=p1*2"
"p4=p3*2"
"in0=inf1/2"
;"d2=3.38983m"

"DELTA=p19+d16"
"TAU1=(1s/((cnst6+0.146*(cnst7-cnst6))*2))-DELTA"
"TAU3=(1s/((cnst7-0.146*(cnst7-cnst6))*2))-DELTA-p3"
;"p32=2*d2"

1 ze
2 d11
3 d11
  d1 BLKGRAD
  (p1 ph10):f1
  TAU1 UNBLKGRAD
  p19:gp1
  d16
  (p3 ph4):f2
  p19:gp1*-0.6667
  d16
  TAU3
  (p3 ph5):f2
  p19:gp1*-0.3333
  d16
  d6
  (p3 ph2):f2
  d0
  (p2 ph10):f1
  d0
  p16:gp2*EA1
  d16
  (p4 ph3):f2
  p16:gp2*EA2
  d16
  6u
  (p3 ph1):f2
  10u pl3:f2
  10u gron3
   (p32:sp29 ph6):f2
  d16 groff pl2:f2
  go=2 ph31
  d11 mc #0 to 3
    F1EA(igrad EA1 & igrad EA2, id0 & ip2*2 & ip31*2)
  50u BLKGRAD
exit

ph1=0 2 2 0
ph2=0
ph3=0
ph4=0
ph5=0
ph6=0
ph10=0
ph20=0
ph21=1
ph31=0 2 2 0



;pl1 :f1 power level for pulse (default)
;pl2 :f2 power level for pulse (default)
;sp29: f2 channel - shaped pulse 180 degree  (adiabatic sweep: z-spoil)
;p1 :f1 90 degree high power pulse
;p2 :f1 180 degree high power pulse
;p3 :f2 90 degree high power pulse
;p4 :f2 180 degree high power pulse
;p16:gradient pulse 1
;p19:gradient pulse 2
;p32: f2 channel - 180 degree shaped pulse (adiabatic sweep: z-spoil)
;d0 :increment delay (3usec)
;d1 :relaxation delay: 1-5*T1
;d6 :delay for evolution of long range couplings
;d11:delay for disk I/O                    [ 30 msec]
;d16:delay for homospoil/gradient recovery [200 usec]
;cnst6   :1J(min), ~125 Hz
;cnst7   :1J(max), ~165 Hz
;MC2     :Echo-Antiecho
;EA1     :Echo-Antiecho gradient program, [+5 -3]
;EA1     :Echo-Antiecho gradient program, [-3 +5]
;NS: 2 * n
;DS: 16
;td1: number of experiments
;FnMODE: echo-antiecho

;
;use gradient ratio:    gp 1 : gp 2 : gp 3
;                        1.4 :  (gpz3*2*TAU2*2)/p16 : (p16*gpz2)/(2*TAU2)

;Inversion sweep width for carbon pulse
;NB Sweepwidth is the enlarged sweepwidth due to the gradient e.g. 5* the actual one!
;sw_inv=gpz3(%)*MaxGradient(G/cm)*DecouplerCoilSize(mm)*1.071


;for z-only gradients:
;gpz1: 1.4% (LPJF)
;gpz2: (gpz3*2*TAU2*2)/p16 (Coherence Selection)
;gpz3: (p16*gpz2)/(2*TAU2) (Adiabatic J-filter)

;use gradient files:
;gpnam1: SINE.100
;gpnam2: RECT.1 (For other shapes, increase to composite for the shape factor)

;Processing

;PH_mod(F1): pk (or no)
;WDW (F2): QSINE (F1): QSINE
;SSB (F2): 4     (F1): 2

;use xfb, xf2m